aboutsummaryrefslogtreecommitdiff
path: root/m4/libcutl.m4
blob: 28f8d0674058984b6c56945ac6bc0dc6ea49020d (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
dnl file      : m4/libcutl.m4
dnl copyright : Copyright (c) 2009-2011 Code Synthesis Tools CC
dnl license   : MIT; see accompanying LICENSE file
dnl
dnl LIBCUTL([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
dnl
dnl
AC_DEFUN([LIBCUTL], [
libcutl_found=no

AC_ARG_WITH(
  [libcutl],
  [AC_HELP_STRING([--with-libcutl=DIR],[location of libcutl build directory])],
  [libcutl_dir=${withval}],
  [libcutl_dir=])

AC_MSG_CHECKING([for libcutl])

# If libcutl_dir was given, add the necessary preprocessor and linker flags.
#
if test x"$libcutl_dir" != x; then
  save_CPPFLAGS="$CPPFLAGS"
  save_LDFLAGS="$LDFLAGS"

  AS_SET_CATFILE([abs_libcutl_dir], [$ac_pwd], [$libcutl_dir])

  CPPFLAGS="$CPPFLAGS -I$abs_libcutl_dir"
  LDFLAGS="$LDFLAGS -L$abs_libcutl_dir/cutl"
fi

save_LIBS="$LIBS"
LIBS="-lcutl $LIBS"

CXX_LIBTOOL_LINK_IFELSE(
AC_LANG_SOURCE([[
#include <cutl/exception.hxx>

void
f ()
{
}

const char*
g ()
{
  try
  {
    f ();
  }
  catch (const cutl::exception& e)
  {
    return e.what ();
  }
  return 0;
}

int
main ()
{
  const char* m (g ());
  return m != 0;
}
]]),
[libcutl_found=yes])

if test x"$libcutl_found" = xno; then
  LIBS="$save_LIBS"

  if test x"$libcutl_dir" != x; then
    CPPFLAGS="$save_CPPFLAGS"
    LDFLAGS="$save_LDFLAGS"
  fi
fi

if test x"$libcutl_found" = xyes; then
  AC_MSG_RESULT([yes])
  $1
else
  AC_MSG_RESULT([no])
  $2
fi
])dnl