Add Windows test scripts

1 files changed, 118 insertions, 0 deletions

diff --git a/test/windows/odb/build.bat b/test/windows/odb/build.bat
new file mode 100755
index 0000000..b97cf62
--- /dev/null
+++ b/test/windows/odb/build.bat
@@ -0,0 +1,118 @@
+@echo off
+rem file      : build.bat
+rem author    : Boris Kolpackov <boris@codesynthesis.com>
+rem copyright : Copyright (c) 2009-2010 Code Synthesis Tools CC
+rem license   : GNU GPL v2; see accompanying LICENSE file
+
+rem
+rem build.bat database vc-version [/Build|/Clean|/Rebuild]
+rem
+
+setlocal
+
+set "confs=Debug Release"
+set "plats=Win32 x64"
+set "failed="
+
+if "_%1_" == "__" (
+  echo no database specified
+  goto usage
+)
+
+if "_%2_" == "__" (
+  echo no VC++ version specified
+  goto usage
+)
+
+if "_%2_" == "_9_" set "vcver=9"
+if "_%2_" == "_10_" set "vcver=10"
+
+if "_%vcver%_" == "__" (
+  echo unknown VC++ version %2
+  goto usage
+)
+
+set "action=%3"
+if "_%action%_" == "__" set "action=/Build"
+
+set "devenv=%DEVENV%"
+if "_%devenv%_" == "__" set "devenv=devenv.com"
+
+goto start
+
+rem
+rem %1 - solution name
+rem %2 - configuration to build
+rem %3 - platform to build
+rem
+:run_build
+  echo.
+  echo building %1 %3 %2
+  "%devenv%" %1 %action% "%2|%3" 2>&1
+  if errorlevel 1 set "failed=%failed% %1\%3\%2"
+goto :eof
+
+:start
+
+for %%d in (libodb libodb-tracer libodb-%1 libodb-boost) do (
+  for %%c in (%confs%) do (
+      for %%p in (%plats%) do (
+        call :run_build %%d/%%d-vc%vcver%.sln %%c %%p
+    )
+  )
+)
+
+if not "_%failed%_" == "__" goto error
+
+for %%c in (%confs%) do (
+    for %%p in (%plats%) do (
+      call :run_build odb-examples/examples-%1-vc%vcver%.sln %%c %%p
+  )
+)
+
+if not "_%failed%_" == "__" goto error
+
+for %%c in (%confs%) do (
+    for %%p in (%plats%) do (
+      call :run_build odb-examples/boost/boost-%1-vc%vcver%.sln %%c %%p
+  )
+)
+
+if not "_%failed%_" == "__" goto error
+
+cd odb-tests
+call build.bat %1 %2 %action%
+if errorlevel 1 (
+  cd ..
+  goto error
+)
+
+cd boost
+call build.bat %1 %2 %action%
+if errorlevel 1 (
+  cd ..\..
+  goto error
+)
+
+echo.
+echo ALL BUILDS SUCCEEDED
+echo.
+goto end
+
+:usage
+echo.
+echo usage: build.bat database vc-version [action]
+echo   valid actions are /Build, /Clean, and /Rebuild
+echo.
+
+:error
+if not "_%failed%_" == "__" (
+  echo.
+  for %%t in (%failed%) do echo FAILED: %%t
+  echo.
+)
+endlocal
+exit /b 1
+
+:end
+endlocal