1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
|
m4_divert(-1)
# file : build/meta/vc9proj.m4
# author : Boris Kolpackov <boris@codesynthesis.com>
# copyright : Copyright (c) 2009-2010 Code Synthesis Tools CC
# license : GNU GPL v2; see accompanying LICENSE file
m4_changequote([, ])
m4_include(__meta_base__[/common.m4])
m4_define([__path_impl__], [m4_translit(__env_impl__([$1]),[/],[\])])
m4_define([__path__], [m4_equote()__path_impl__([$1])[]m4_dquote()])
m4_define([__file_impl__], [__env_impl__([$1])])
m4_define([__file__], [m4_equote()__file_impl__([$1])[]m4_dquote()])
# header
#
m4_define([__header_entry_impl__],
[ <ClInclude Include="[$1]" />])
m4_define([__header_entry__],
[m4_equote()__header_entry_impl__([$1])[]m4_dquote()])
m4_define([__header_entries_impl__],
[m4_foreach_w([__f], __path_impl__([$1]), [
__header_entry_impl__(__f)])])
m4_define([__header_entries__],
[m4_equote()__header_entries_impl__([$1])[]m4_dquote()])
# header_filter
#
m4_define([__header_filter_entry_impl__],
[ <ClInclude Include="[$1]">
<Filter>Header Files</Filter>
</ClInclude>])
m4_define([__header_filter_entry__],
[m4_equote()__header_filter_entry_impl__([$1])[]m4_dquote()])
m4_define([__header_filter_entries_impl__],
[m4_foreach_w([__f], __path_impl__([$1]), [
__header_filter_entry_impl__(__f)])])
m4_define([__header_filter_entries__],
[m4_equote()__header_filter_entries_impl__([$1])[]m4_dquote()])
# source
#
# $1 - configuration
# $2 - directory
#
m4_define([__source_config_entry_impl__],
[ <ObjectFileName m4_dnl
Condition="'$(Configuration)|$(Platform)'==m4_dnl
'[]m4_patsubst([$1], ["], [])'">m4_dnl
$(IntDir)\[$2]\</ObjectFileName>])
m4_define([__source_entry_body__],
[m4_ifelse([$1], [$2],
[ <ClCompile Include="[$1]" />],
[ <ClCompile Include="[$1]">m4_dnl
m4_foreach([__c],
[__value_impl__([configurations])],
[
__source_config_entry_impl__(__c, [$2])])
</ClCompile>])])
m4_define([__source_entry_impl__],
[__source_entry_body__([$1],
m4_patsubst([$1], [^\(.*\)\\\(.*\)$], [\1]))])
m4_define([__source_entry__],
[m4_equote()__source_entry_impl__([$1])[]m4_dquote()])
m4_define([__source_entries_impl__],
[m4_foreach_w([__f], __path_impl__([$1]), [
__source_entry_impl__(__f)])])
m4_define([__source_entries__],
[m4_equote()__source_entries_impl__([$1])[]m4_dquote()])
# source_filter
#
m4_define([__source_filter_entry_impl__],
[ <ClCompile Include="[$1]">
<Filter>Source Files</Filter>
</ClCompile>])
m4_define([__source_filter_entry__],
[m4_equote()__source_filter_entry_impl__([$1])[]m4_dquote()])
m4_define([__source_filter_entries_impl__],
[m4_foreach_w([__f], __path_impl__([$1]), [
__source_filter_entry_impl__(__f)])])
m4_define([__source_filter_entries__],
[m4_equote()__source_filter_entries_impl__([$1])[]m4_dquote()])
# custom_build
#
m4_define([__custom_build_entry_tag_impl__],
[ <[$1] Condition="'$(Configuration)|$(Platform)'==m4_dnl
'[]m4_patsubst([$2], ["], [])'">[$3]</[$1]>])
m4_define([__custom_build_entry_impl__],
[ <CustomBuild Include="[$1]">m4_dnl
m4_foreach([__c],
[__value_impl__([configurations])],
[
__custom_build_entry_tag_impl__([Message], __c, [$2])
__custom_build_entry_tag_impl__([Command], __c, [$3])
__custom_build_entry_tag_impl__([Outputs], __c, [$4];%(Outputs))])
</CustomBuild>])
# (file, cmd-description, cmd, output;output)
#
m4_define([__custom_build_entry__],
[m4_equote()__custom_build_entry_impl__([$1],
[$2], [$3], [$4])[]m4_dquote()])
# Disable comments and quoting.
#
m4_changecom([])
m4_changequote([])
m4_divert(0)m4_dnl
|
