Add code for Qt profile dist build

5 files changed, 186 insertions, 1 deletions

diff --git a/Makefile.am b/Makefile.am
index e991f53..e3504b3 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -13,5 +13,9 @@ if ODB_EXAMPLES_BOOST
 SUBDIRS += __path__(boost_dirs)
 endif
 
+if ODB_EXAMPLES_QT
+SUBDIRS += __path__(qt_dirs)
+endif
+
 EXTRA_DIST = __file__(extra_dist)
 ACLOCAL_AMFLAGS = -I m4
diff --git a/configure.ac b/configure.ac
index 9c38a3d..c617200 100644
--- a/configure.ac
+++ b/configure.ac
@@ -53,6 +53,17 @@ LIBODB_BOOST([], [odb_examples_boost=no])
 
 AM_CONDITIONAL([ODB_EXAMPLES_BOOST], [test x$odb_examples_boost != xno])
 
+# Check for Qt
+#
+odb_examples_qt=yes
+LIBQTCORE([],[odb_examples_qt=no])
+
+# Check for libodb-qt
+#
+LIBODB_QT([], [odb_examples_qt=no])
+
+AM_CONDITIONAL([ODB_EXAMPLES_QT], [test x$odb_examples_qt != xno])
+
 # Check which database we are using.
 #
 DATABASE
diff --git a/m4/libodb-qt.m4 b/m4/libodb-qt.m4
new file mode 100644
index 0000000..7e6b31e
--- /dev/null
+++ b/m4/libodb-qt.m4
@@ -0,0 +1,84 @@
+dnl file      : m4/libodb-qt.m4
+dnl author    : Boris Kolpackov <boris@codesynthesis.com>
+dnl copyright : Copyright (c) 2009-2011 Code Synthesis Tools CC
+dnl license   : GNU GPL v2; see accompanying LICENSE file
+dnl
+dnl LIBODB_QT([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
+dnl
+dnl
+AC_DEFUN([LIBODB_QT], [
+libodb_qt_found=no
+
+AC_ARG_WITH(
+  [libodb-qt],
+  [AC_HELP_STRING([--with-libodb-qt=DIR],[location of libodb-qt build directory])],
+  [libodb_qt_dir=${withval}],
+  [libodb_qt_dir=])
+
+AC_MSG_CHECKING([for libodb-qt])
+
+# If libodb_qt_dir was given, add the necessary preprocessor and
+# linker flags.
+#
+if test x"$libodb_qt_dir" != x; then
+  save_CPPFLAGS="$CPPFLAGS"
+  save_LDFLAGS="$LDFLAGS"
+
+  AS_SET_CATFILE([abs_libodb_qt_dir], [$ac_pwd], [$libodb_qt_dir])
+
+  CPPFLAGS="$CPPFLAGS -I$abs_libodb_qt_dir"
+  LDFLAGS="$LDFLAGS -L$abs_libodb_qt_dir/odb/qt"
+fi
+
+save_LIBS="$LIBS"
+LIBS="-lodb-qt $LIBS"
+
+CXX_LIBTOOL_LINK_IFELSE(
+AC_LANG_SOURCE([[
+#include <odb/qt/exception.hxx>
+
+void
+f ()
+{
+}
+
+const char*
+g ()
+{
+  try
+  {
+    f ();
+  }
+  catch (const odb::qt::exception& e)
+  {
+    return e.what ();
+  }
+  return 0;
+}
+
+int
+main ()
+{
+  const char* m (g ());
+  return m != 0;
+}
+]]),
+[libodb_qt_found=yes])
+
+if test x"$libodb_qt_found" = xno; then
+  LIBS="$save_LIBS"
+
+  if test x"$libodb_qt_dir" != x; then
+    CPPFLAGS="$save_CPPFLAGS"
+    LDFLAGS="$save_LDFLAGS"
+  fi
+fi
+
+if test x"$libodb_qt_found" = xyes; then
+  AC_MSG_RESULT([yes])
+  $1
+else
+  AC_MSG_RESULT([no])
+  $2
+fi
+])dnl
diff --git a/m4/libqt.m4 b/m4/libqt.m4
new file mode 100644
index 0000000..b79e0a8
--- /dev/null
+++ b/m4/libqt.m4
@@ -0,0 +1,86 @@
+dnl file      : m4/libqt.m4
+dnl author    : Boris Kolpackov <boris@codesynthesis.com>
+dnl copyright : Copyright (c) 2009-2011 Code Synthesis Tools CC
+dnl license   : GNU GPL v2; see accompanying LICENSE file
+dnl
+dnl LIBQTCORE([ACTION-IF-FOUND[,ACTION-IF-NOT-FOUND]])
+dnl
+dnl
+AC_DEFUN([LIBQTCORE], [
+libqt_found=no
+
+AC_PATH_PROG([pkg_config],[pkg-config])
+
+AC_MSG_CHECKING([for QtCore])
+
+# First check for QtCore using default CPPFLAGS/LDFLAGS.
+#
+save_LIBS="$LIBS"
+LIBS="-lQtCore $LIBS"
+
+CXX_LIBTOOL_LINK_IFELSE(
+AC_LANG_SOURCE([[
+#include <string>
+#include <QString>
+
+int
+main ()
+{
+  QString qs ("test");
+  std::string ss (qs.toStdString ());
+  return ss.size () != 0;
+}
+]]),
+[
+libqt_found=yes
+])
+
+# If default CPPFLAGS/LDFLAGS didn't work, try to discover
+# them using pkg-config.
+#
+if test x"$libqt_found" = xno; then
+  LIBS="$save_LIBS"
+
+  if test x"$pkg_config" != x; then
+    if $pkg_config --exists QtCore; then
+      save_CPPFLAGS="$CPPFLAGS"
+      save_LIBS="$LIBS"
+
+      CPPFLAGS=`$pkg_config --cflags QtCore`
+      LIBS=`$pkg_config --libs QtCore`
+
+      CPPFLAGS="$CPPFLAGS $save_CPPFLAGS"
+      LIBS="$LIBS $save_LIBS"
+
+      CXX_LIBTOOL_LINK_IFELSE(
+AC_LANG_SOURCE([[
+#include <string>
+#include <QString>
+
+int
+main ()
+{
+  QString qs ("test");
+  std::string ss (qs.toStdString ());
+  return ss.size () != 0;
+}
+]]),
+[
+libqt_found=yes
+])
+     if test x"$libqt_found" = xno; then
+       CPPFLAGS="$save_CPPFLAGS"
+       LIBS="$save_LIBS"
+     fi
+    fi
+  fi
+fi
+
+if test x"$libqt_found" = xyes; then
+  AC_MSG_RESULT([yes])
+  $1
+else
+  AC_MSG_RESULT([no])
+  $2
+fi
+])dnl
diff --git a/test.bat b/test.bat
index 58330d3..19f1e16 100644
--- a/test.bat
+++ b/test.bat
@@ -6,7 +6,7 @@ rem license   : GNU GPL v2; see accompanying LICENSE file
 
 setlocal
 
-set "tests=__path__(dirs) __path__(tr1_dirs) __path__(boost_dirs)"
+set "tests=__path__(dirs) __path__(tr1_dirs) __path__(boost_dirs) __path__(qt_dirs)"
 set "confs=__path__(configurations)"
 set "plats=__path__(platforms)"
 set "curdir=%CD%"