From 605e4dee303f2a7b3b493e7a73faa09e61d88839 Mon Sep 17 00:00:00 2001
From: Boris Kolpackov <boris@codesynthesis.com>
Date: Tue, 17 Jan 2012 16:46:51 +0200
Subject: Autotools and VC++ build support for SQL Server

---
 mssql-driver.bat | 63 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)
 create mode 100644 mssql-driver.bat

(limited to 'mssql-driver.bat')

diff --git a/mssql-driver.bat b/mssql-driver.bat
new file mode 100644
index 0000000..55ed487
--- /dev/null
+++ b/mssql-driver.bat
@@ -0,0 +1,63 @@
+@echo off
+rem file      : mssql-driver.bat
+rem author    : Boris Kolpackov <boris@codesynthesis.com>
+rem copyright : Copyright (c) 2009-2011 Code Synthesis Tools CC
+rem license   : GNU GPL v2; see accompanying LICENSE file
+
+rem
+rem mssql-driver.bat sql-file
+rem
+rem Run the mssql client on the SQL file specified. Adjust the
+rem options below to match your SQL Server setup.
+rem
+
+setlocal
+
+set "options=%MSSQL_OPTIONS%"
+
+rem User.
+rem
+set "options=%options% -U odb_test"
+
+rem Password.
+rem
+set "options=%options% -P odb_test"
+
+rem Database name.
+rem
+set "options=%options% -d odb_test"
+
+rem SQL Server instance address.
+rem
+rem set "options=%options% -S host\instance"
+rem set "options=%options% -S tcp:host,port"
+
+rem Standard options.
+rem
+set "options=%options% -x -r -b"
+
+set "mssql=%MSSQL_CLIENT%"
+
+if "_%mssql%_" == "__" set "mssql=sqlcmd"
+
+if "_%1_" == "__" (
+  echo no sql file specified
+  goto usage
+)
+
+%mssql% %options% -i %1
+
+if errorlevel 1 goto error
+goto end
+
+:usage
+echo.
+echo usage: mssql-driver.bat sql-file
+echo.
+
+:error
+endlocal
+exit /b 1
+
+:end
+endlocal
-- 
cgit v1.1