From 5aaec95bbfb066130ecac03eece3813cee61a3e1 Mon Sep 17 00:00:00 2001
From: Boris Kolpackov <boris@codesynthesis.com>
Date: Thu, 17 Feb 2011 14:50:11 +0200
Subject: Add test infrastructure for boost profile

---
 boost/common/test.bat | 81 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 81 insertions(+)
 create mode 100644 boost/common/test.bat

(limited to 'boost/common/test.bat')

diff --git a/boost/common/test.bat b/boost/common/test.bat
new file mode 100644
index 0000000..a5f035a
--- /dev/null
+++ b/boost/common/test.bat
@@ -0,0 +1,81 @@
+@echo off
+rem file      : boost/common/test.bat
+rem author    : Boris Kolpackov <boris@codesynthesis.com>
+rem copyright : Copyright (c) 2009-2011 Code Synthesis Tools CC
+rem license   : GNU GPL v2; see accompanying LICENSE file
+
+setlocal
+
+set "tests=__path__(dirs)"
+set "confs=__path__(configurations)"
+set "plats=__path__(platforms)"
+set "curdir=%CD%"
+set "topdir=%curdir%\..\.."
+set "failed="
+
+if "_%1_" == "__" (
+  echo no database specified
+  goto usage
+)
+
+goto start
+
+rem
+rem %1 - test directory
+rem %2 - configuration
+rem %3 - platform
+rem %4 - database
+rem
+:run_test
+  cd %1
+
+  if "_%3_" == "_Win32_" (
+    set "dir=%2"
+  ) else (
+    set "dir=%3\%2"
+  )
+
+  if exist %dir%\driver.exe (
+    echo %1\%3\%2
+    call %topdir%\tester.bat %4 %2 %3
+    if errorlevel 1 (
+      set "failed=%failed% %1\%3\%2"
+    )
+  )
+
+  cd %curdir%
+goto :eof
+
+:start
+
+for %%t in (%tests%) do (
+  for %%c in (%confs%) do (
+    for %%p in (%plats%) do (
+      call :run_test %%t %%c %%p %1
+    )
+  )
+)
+
+if not "_%failed%_" == "__" goto error
+
+echo.
+echo ALL TESTS PASSED
+echo.
+goto end
+
+:usage
+echo.
+echo usage: test.bat database
+echo.
+
+:error
+if not "_%failed%_" == "__" (
+  echo.
+  for %%t in (%failed%) do echo FAILED: %%t
+  echo.
+)
+endlocal
+exit /b 1
+
+:end
+endlocal
-- 
cgit v1.1