From 19d0eb2adcda31d9919bca8fef98cb1871b4ce54 Mon Sep 17 00:00:00 2001
From: Boris Kolpackov <boris@codesynthesis.com>
Date: Tue, 14 Sep 2010 19:01:49 +0200
Subject: Add automake and VC++ builds (meta-build)

---
 m4/disable-rpath.m4 | 26 ++++++++++++++++++++++++++
 m4/libtool-link.m4  | 31 +++++++++++++++++++++++++++++++
 m4/pkgconfig.m4     | 13 +++++++++++++
 3 files changed, 70 insertions(+)
 create mode 100644 m4/disable-rpath.m4
 create mode 100644 m4/libtool-link.m4
 create mode 100644 m4/pkgconfig.m4

(limited to 'm4')

diff --git a/m4/disable-rpath.m4 b/m4/disable-rpath.m4
new file mode 100644
index 0000000..4540e66
--- /dev/null
+++ b/m4/disable-rpath.m4
@@ -0,0 +1,26 @@
+dnl file      : m4/disable-rpath.m4
+dnl author    : Boris Kolpackov <boris@codesynthesis.com>
+dnl copyright : Copyright (c) 2009-2010 Code Synthesis Tools CC
+dnl license   : MIT; see accompanying LICENSE file
+dnl
+AC_DEFUN([DISABLE_RPATH],[
+
+AC_MSG_CHECKING([whether to use rpath])
+AC_ARG_ENABLE(
+  [rpath],
+  [AC_HELP_STRING([--disable-rpath], [patch libtool to not use rpath])],
+  [libtool_rpath="$enable_rpath"],
+  [libtool_rpath="yes"])
+AC_MSG_RESULT($libtool_rpath)
+
+# Patch libtool to not use rpath if requested.
+#
+AC_CONFIG_COMMANDS(
+  [libtool-rpath-patch],
+  [if test "$libtool_use_rpath" = "no"; then
+     sed < libtool > libtool-2 's/^hardcode_libdir_flag_spec.*$'/'hardcode_libdir_flag_spec=" -D__LIBTOOL_NO_RPATH__ "/'
+     mv libtool-2 libtool
+     chmod 755 libtool
+  fi],
+  [libtool_use_rpath=$libtool_rpath])
+])dnl
diff --git a/m4/libtool-link.m4 b/m4/libtool-link.m4
new file mode 100644
index 0000000..4748520
--- /dev/null
+++ b/m4/libtool-link.m4
@@ -0,0 +1,31 @@
+dnl file      : m4/libtool-link.m4
+dnl author    : Boris Kolpackov <boris@codesynthesis.com>
+dnl copyright : Copyright (c) 2009-2010 Code Synthesis Tools CC
+dnl license   : MIT; see accompanying LICENSE file
+dnl
+dnl
+dnl CXX_LIBTOOL_LINK_IFELSE (input, [action-if-true], [action-if-false])
+dnl
+dnl Similar to AC_LINK_IFELSE except it uses libtool to perform the
+dnl linking and it does this using the C++ compiler.
+dnl
+AC_DEFUN([CXX_LIBTOOL_LINK_IFELSE],[
+AC_LANG_SAVE
+save_CXX="$CXX"
+CXX="./libtool --tag=CXX --mode=link $CXX -no-install"
+AC_LANG(C++)
+
+if test -d .libs; then
+  delete_libs_dir=no
+else
+  delete_libs_dir=yes
+fi
+
+AC_LINK_IFELSE([$1], [$2], [$3])
+
+if test x"$delete_libs_dir" != xyes; then
+  rm -rf .libs
+fi
+
+CXX="$save_CXX"
+AC_LANG_RESTORE])dnl
diff --git a/m4/pkgconfig.m4 b/m4/pkgconfig.m4
new file mode 100644
index 0000000..64d90f1
--- /dev/null
+++ b/m4/pkgconfig.m4
@@ -0,0 +1,13 @@
+dnl file      : m4/pkgconfig.m4
+dnl author    : Boris Kolpackov <boris@codesynthesis.com>
+dnl copyright : Copyright (c) 2009-2010 Code Synthesis Tools CC
+dnl license   : MIT; see accompanying LICENSE file
+dnl
+AC_DEFUN([PKGCONFIG],[
+AC_ARG_WITH(
+  [pkgconfigdir],
+  [AC_HELP_STRING([--with-pkgconfigdir=DIR],[location of pkgconfig dir (default is libdir/pkgconfig)])],
+  [pkgconfigdir=${withval}],
+  [pkgconfigdir='${libdir}/pkgconfig'])
+AC_SUBST([pkgconfigdir])
+])dnl
-- 
cgit v1.1