Add support for disabling threads

5 files changed, 377 insertions, 46 deletions

diff --git a/configure.ac b/configure.ac
index 18f6dd1..49da0b5 100644
--- a/configure.ac
+++ b/configure.ac
@@ -44,7 +44,7 @@ if test x"$external_boost" != xno; then
   LIBBOOST_REGEX([],[boost_found=no])
   LIBBOOST_SYSTEM
 
-  if test x"$boost_found" == xno; then
+  if test x"$boost_found" = xno; then
     AC_MSG_ERROR([boost regex is not found; consider using CPPFLAGS/LDFLAGS or --with-boost=DIR to specify its location])
   fi
 
@@ -55,6 +55,14 @@ fi
 
 AM_CONDITIONAL([LIBCUTL_EXTERNAL_BOOST], [test x"$external_boost" != xno])
 
+# Check for threads. For now only internal Boost uses threads so don't
+# configure them if we are using external Boost.
+#
+if test x"$external_boost" = xno; then
+  THREADS
+  AS_IF([test x$threads = xnone],
+        [AC_DEFINE([LIBCUTL_DISABLE_THREADS], [1], [Disable threads.])])
+fi
 
 # Define LIBODB_STATIC_LIB if we are build static library on certain platforms.
 #
diff --git a/cutl/details/boost/config/user.hpp b/cutl/details/boost/config/user.hpp
index b90b59c..be97597 100644
--- a/cutl/details/boost/config/user.hpp
+++ b/cutl/details/boost/config/user.hpp
@@ -1,14 +1,16 @@
 //  boost/config/user.hpp  ---------------------------------------------------//
 
-//  (C) Copyright John Maddock 2001. 
-//  Use, modification and distribution are subject to the 
-//  Boost Software License, Version 1.0. (See accompanying file 
+//  (C) Copyright John Maddock 2001.
+//  Use, modification and distribution are subject to the
+//  Boost Software License, Version 1.0. (See accompanying file
 //  LICENSE_1_0.txt or copy at http://www.boost.org/LICENSE_1_0.txt)
 
 //
 // libcutl-specific configuration
 //
 
+#include <cutl/details/config.hxx>
+
 // We have removed those.
 //
 #define BOOST_MPL_CFG_NO_PREPROCESSED_HEADERS
@@ -17,6 +19,10 @@
 //
 #define BOOST_ALL_NO_LIB
 
+#ifdef LIBCUTL_DISABLE_THREADS
+#  define BOOST_DISABLE_THREADS 1
+#endif
+
 //
 //  Use this file to define a site and compiler specific
 //  configuration policy:
@@ -74,60 +80,57 @@
 // even when available:
 // #define BOOST_DISABLE_WIN32
 
-// BOOST_DISABLE_ABI_HEADERS: Stops boost headers from including any 
-// prefix/suffix headers that normally control things like struct 
-// packing and alignment. 
+// BOOST_DISABLE_ABI_HEADERS: Stops boost headers from including any
+// prefix/suffix headers that normally control things like struct
+// packing and alignment.
 // #define BOOST_DISABLE_ABI_HEADERS
 
 // BOOST_ABI_PREFIX: A prefix header to include in place of whatever
-// boost.config would normally select, any replacement should set up 
-// struct packing and alignment options as required. 
+// boost.config would normally select, any replacement should set up
+// struct packing and alignment options as required.
 // #define BOOST_ABI_PREFIX my-header-name
 
-// BOOST_ABI_SUFFIX: A suffix header to include in place of whatever 
-// boost.config would normally select, any replacement should undo 
-// the effects of the prefix header. 
+// BOOST_ABI_SUFFIX: A suffix header to include in place of whatever
+// boost.config would normally select, any replacement should undo
+// the effects of the prefix header.
 // #define BOOST_ABI_SUFFIX my-header-name
 
-// BOOST_ALL_DYN_LINK: Forces all libraries that have separate source, 
-// to be linked as dll's rather than static libraries on Microsoft Windows 
-// (this macro is used to turn on __declspec(dllimport) modifiers, so that 
-// the compiler knows which symbols to look for in a dll rather than in a 
-// static library).  Note that there may be some libraries that can only 
-// be statically linked (Boost.Test for example) and others which may only 
-// be dynamically linked (Boost.Threads for example), in these cases this 
+// BOOST_ALL_DYN_LINK: Forces all libraries that have separate source,
+// to be linked as dll's rather than static libraries on Microsoft Windows
+// (this macro is used to turn on __declspec(dllimport) modifiers, so that
+// the compiler knows which symbols to look for in a dll rather than in a
+// static library).  Note that there may be some libraries that can only
+// be statically linked (Boost.Test for example) and others which may only
+// be dynamically linked (Boost.Threads for example), in these cases this
 // macro has no effect.
 // #define BOOST_ALL_DYN_LINK
- 
-// BOOST_WHATEVER_DYN_LINK: Forces library "whatever" to be linked as a dll 
-// rather than a static library on Microsoft Windows: replace the WHATEVER 
-// part of the macro name with the name of the library that you want to 
-// dynamically link to, for example use BOOST_DATE_TIME_DYN_LINK or 
-// BOOST_REGEX_DYN_LINK etc (this macro is used to turn on __declspec(dllimport) 
-// modifiers, so that the compiler knows which symbols to look for in a dll 
-// rather than in a static library).  
-// Note that there may be some libraries that can only be statically linked 
-// (Boost.Test for example) and others which may only be dynamically linked 
+
+// BOOST_WHATEVER_DYN_LINK: Forces library "whatever" to be linked as a dll
+// rather than a static library on Microsoft Windows: replace the WHATEVER
+// part of the macro name with the name of the library that you want to
+// dynamically link to, for example use BOOST_DATE_TIME_DYN_LINK or
+// BOOST_REGEX_DYN_LINK etc (this macro is used to turn on __declspec(dllimport)
+// modifiers, so that the compiler knows which symbols to look for in a dll
+// rather than in a static library).
+// Note that there may be some libraries that can only be statically linked
+// (Boost.Test for example) and others which may only be dynamically linked
 // (Boost.Threads for example), in these cases this macro is unsupported.
 // #define BOOST_WHATEVER_DYN_LINK
- 
-// BOOST_ALL_NO_LIB: Tells the config system not to automatically select 
-// which libraries to link against.  
-// Normally if a compiler supports #pragma lib, then the correct library 
-// build variant will be automatically selected and linked against, 
-// simply by the act of including one of that library's headers.  
+
+// BOOST_ALL_NO_LIB: Tells the config system not to automatically select
+// which libraries to link against.
+// Normally if a compiler supports #pragma lib, then the correct library
+// build variant will be automatically selected and linked against,
+// simply by the act of including one of that library's headers.
 // This macro turns that feature off.
 // #define BOOST_ALL_NO_LIB
- 
-// BOOST_WHATEVER_NO_LIB: Tells the config system not to automatically 
-// select which library to link against for library "whatever", 
-// replace WHATEVER in the macro name with the name of the library; 
-// for example BOOST_DATE_TIME_NO_LIB or BOOST_REGEX_NO_LIB.  
-// Normally if a compiler supports #pragma lib, then the correct library 
-// build variant will be automatically selected and linked against, simply 
-// by the act of including one of that library's headers.  This macro turns 
+
+// BOOST_WHATEVER_NO_LIB: Tells the config system not to automatically
+// select which library to link against for library "whatever",
+// replace WHATEVER in the macro name with the name of the library;
+// for example BOOST_DATE_TIME_NO_LIB or BOOST_REGEX_NO_LIB.
+// Normally if a compiler supports #pragma lib, then the correct library
+// build variant will be automatically selected and linked against, simply
+// by the act of including one of that library's headers.  This macro turns
 // that feature off.
 // #define BOOST_WHATEVER_NO_LIB
- 
-
-
diff --git a/cutl/details/config.h.in b/cutl/details/config.h.in
index afd7824..cc16e60 100644
--- a/cutl/details/config.h.in
+++ b/cutl/details/config.h.in
@@ -8,6 +8,7 @@
 #ifndef CUTL_DETAILS_CONFIG_H
 #define CUTL_DETAILS_CONFIG_H
 
+#undef LIBCUTL_DISABLE_THREADS
 #undef LIBCUTL_STATIC_LIB
 #undef LIBCUTL_EXTERNAL_BOOST
 
diff --git a/m4/acx-pthread.m4 b/m4/acx-pthread.m4
new file mode 100644
index 0000000..204b32d
--- /dev/null
+++ b/m4/acx-pthread.m4
@@ -0,0 +1,259 @@
+dnl
+dnl NOTE: This file was modified. See the comments starting with 'CS:'
+dnl for more information. In particular, it was changed to use C++
+dnl instead of C.
+dnl
+dnl @synopsis ACX_PTHREAD([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
+dnl
+dnl @summary figure out how to build C++ programs using POSIX threads
+dnl
+dnl This macro figures out how to build C++ programs using POSIX threads.
+dnl It sets the PTHREAD_LIBS output variable to the threads library and
+dnl linker flags, and the PTHREAD_CXXFLAGS output variable to any special
+dnl C++ compiler flags that are needed. (The user can also force certain
+dnl compiler flags/libs to be tested by setting these environment
+dnl variables.)
+dnl
+dnl Also sets PTHREAD_CXX to any special C++ compiler that is needed for
+dnl multi-threaded programs (defaults to the value of CXX otherwise).
+dnl (This is necessary on AIX to use the special xlC_r compiler alias.)
+dnl
+dnl NOTE: You are assumed to not only compile your program with these
+dnl flags, but also link it with them as well. e.g. you should link
+dnl with $PTHREAD_CXX $CXXFLAGS $PTHREAD_CXXFLAGS $LDFLAGS ... $PTHREAD_LIBS
+dnl $LIBS
+dnl
+dnl If you are only building threads programs, you may wish to use
+dnl these variables in your default LIBS, CXXFLAGS, and CXX:
+dnl
+dnl        LIBS="$PTHREAD_LIBS $LIBS"
+dnl        CXXFLAGS="$CXXFLAGS $PTHREAD_CXXFLAGS"
+dnl        CXX="$PTHREAD_CXX"
+dnl
+dnl In addition, if the PTHREAD_CREATE_JOINABLE thread-attribute
+dnl constant has a nonstandard name, defines PTHREAD_CREATE_JOINABLE to
+dnl that name (e.g. PTHREAD_CREATE_UNDETACHED on AIX).
+dnl
+dnl ACTION-IF-FOUND is a list of shell commands to run if a threads
+dnl library is found, and ACTION-IF-NOT-FOUND is a list of commands to
+dnl run it if it is not found. If ACTION-IF-FOUND is not specified, the
+dnl default action will define HAVE_PTHREAD.
+dnl
+dnl Please let the authors know if this macro fails on any platform, or
+dnl if you have any other suggestions or comments. This macro was based
+dnl on work by SGJ on autoconf scripts for FFTW (www.fftw.org) (with
+dnl help from M. Frigo), as well as ac_pthread and hb_pthread macros
+dnl posted by Alejandro Forero Cuervo to the autoconf macro repository.
+dnl We are also grateful for the helpful feedback of numerous users.
+dnl
+dnl @category InstalledPackages
+dnl @author Steven G. Johnson <stevenj@alum.mit.edu>
+dnl @version 2006-05-29
+dnl @license GPLWithACException
+
+AC_DEFUN([ACX_PTHREAD], [
+AC_REQUIRE([AC_CANONICAL_HOST])
+AC_LANG_SAVE
+AC_LANG(C++)
+acx_pthread_ok=no
+
+# We used to check for pthread.h first, but this fails if pthread.h
+# requires special compiler flags (e.g. on True64 or Sequent).
+# It gets checked for in the link test anyway.
+
+# First of all, check if the user has set any of the PTHREAD_LIBS,
+# etcetera environment variables, and if threads linking works using
+# them:
+if test x"$PTHREAD_LIBS$PTHREAD_CXXFLAGS" != x; then
+        save_CXXFLAGS="$CXXFLAGS"
+        CXXFLAGS="$CXXFLAGS $PTHREAD_CXXFLAGS"
+        save_LIBS="$LIBS"
+        LIBS="$PTHREAD_LIBS $LIBS"
+        AC_MSG_CHECKING([for pthread_join in LIBS=$PTHREAD_LIBS with CXXFLAGS=$PTHREAD_CXXFLAGS])
+        AC_TRY_LINK_FUNC(pthread_join, acx_pthread_ok=yes)
+        AC_MSG_RESULT($acx_pthread_ok)
+        if test x"$acx_pthread_ok" = xno; then
+                PTHREAD_LIBS=""
+                PTHREAD_CXXFLAGS=""
+        fi
+        LIBS="$save_LIBS"
+        CXXFLAGS="$save_CXXFLAGS"
+fi
+
+# We must check for the threads library under a number of different
+# names; the ordering is very important because some systems
+# (e.g. DEC) have both -lpthread and -lpthreads, where one of the
+# libraries is broken (non-POSIX).
+
+# Create a list of thread flags to try.  Items starting with a "-" are
+# C compiler flags, and other items are library names, except for "none"
+# which indicates that we try without any flags at all, and "pthread-config"
+# which is a program returning the flags for the Pth emulation library.
+
+# CS: On GNU/Linux with gcc both -pthread and -lpthread are valid.
+# However, libtool links libraries with -nostdlib which results in
+# -pthread being stripped from the linker command line. To resolve
+# this we move pthread from after -mthreads to after pthreads.
+#
+acx_pthread_flags="pthreads pthread none -Kthread -kthread lthread -pthread -pthreads -mthreads --thread-safe -mt pthread-config"
+
+# The ordering *is* (sometimes) important.  Some notes on the
+# individual items follow:
+
+# pthreads: AIX (must check this before -lpthread)
+# none: in case threads are in libc; should be tried before -Kthread and
+#       other compiler flags to prevent continual compiler warnings
+# -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
+# -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
+# lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
+# -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads)
+# -pthreads: Solaris/gcc
+# -mthreads: Mingw32/gcc, Lynx/gcc
+# -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
+#      doesn't hurt to check since this sometimes defines pthreads too;
+#      also defines -D_REENTRANT)
+#      ... -mt is also the pthreads flag for HP/aCC
+# pthread: Linux, etcetera
+# --thread-safe: KAI C++
+# pthread-config: use pthread-config program (for GNU Pth library)
+
+case "${host_cpu}-${host_os}" in
+        *solaris*)
+
+        # On Solaris (at least, for some versions), libc contains stubbed
+        # (non-functional) versions of the pthreads routines, so link-based
+        # tests will erroneously succeed.  (We need to link with -pthreads/-mt/
+        # -lpthread.)  (The stubs are missing pthread_cleanup_push, or rather
+        # a function called by this macro, so we could check for that, but
+        # who knows whether they'll stub that too in a future libc.)  So,
+        # we'll just look for -pthreads and -lpthread first:
+
+        # CS: Move -mt to the front of the list; Sun CC will use -mt,
+        # gcc will use -pthreads.
+        #
+        acx_pthread_flags="-mt -pthreads pthread -pthread $acx_pthread_flags"
+        ;;
+esac
+
+if test x"$acx_pthread_ok" = xno; then
+for flag in $acx_pthread_flags; do
+
+        case $flag in
+                none)
+                AC_MSG_CHECKING([whether pthreads work without any flags])
+                ;;
+
+                -*)
+                AC_MSG_CHECKING([whether pthreads work with $flag])
+                PTHREAD_CXXFLAGS="$flag"
+                ;;
+
+		pthread-config)
+		AC_CHECK_PROG(acx_pthread_config, pthread-config, yes, no)
+		if test x"$acx_pthread_config" = xno; then continue; fi
+		PTHREAD_CXXFLAGS="`pthread-config --cflags`"
+		PTHREAD_LIBS="`pthread-config --ldflags` `pthread-config --libs`"
+		;;
+
+                *)
+                AC_MSG_CHECKING([for the pthreads library -l$flag])
+                PTHREAD_LIBS="-l$flag"
+                ;;
+        esac
+
+        save_LIBS="$LIBS"
+        save_CXXFLAGS="$CXXFLAGS"
+        LIBS="$PTHREAD_LIBS $LIBS"
+        CXXFLAGS="$CXXFLAGS $PTHREAD_CXXFLAGS"
+
+        # Check for various functions.  We must include pthread.h,
+        # since some functions may be macros.  (On the Sequent, we
+        # need a special flag -Kthread to make this header compile.)
+        # We check for pthread_join because it is in -lpthread on IRIX
+        # while pthread_create is in libc.  We check for pthread_attr_init
+        # due to DEC craziness with -lpthreads.  We check for
+        # pthread_cleanup_push because it is one of the few pthread
+        # functions on Solaris that doesn't have a non-functional libc stub.
+        # We try pthread_create on general principles.
+        #
+        AC_TRY_LINK([#include <pthread.h>],
+                    [pthread_t th; pthread_join(th, 0);
+                     pthread_attr_init(0); pthread_cleanup_push(0, 0);
+                     pthread_create(0,0,0,0); pthread_cleanup_pop(0);],
+                    [acx_pthread_ok=yes])
+
+        LIBS="$save_LIBS"
+        CXXFLAGS="$save_CXXFLAGS"
+
+        AC_MSG_RESULT($acx_pthread_ok)
+        if test "x$acx_pthread_ok" = xyes; then
+                break;
+        fi
+
+        PTHREAD_LIBS=""
+        PTHREAD_CXXFLAGS=""
+done
+fi
+
+# Various other checks:
+if test "x$acx_pthread_ok" = xyes; then
+        save_LIBS="$LIBS"
+        LIBS="$PTHREAD_LIBS $LIBS"
+        save_CXXFLAGS="$CXXFLAGS"
+        CXXFLAGS="$CXXFLAGS $PTHREAD_CXXFLAGS"
+
+dnl     # Detect AIX lossage: JOINABLE attribute is called UNDETACHED.
+dnl	AC_MSG_CHECKING([for joinable pthread attribute])
+dnl	attr_name=unknown
+dnl	for attr in PTHREAD_CREATE_JOINABLE PTHREAD_CREATE_UNDETACHED; do
+dnl	    AC_TRY_LINK([#include <pthread.h>], [int attr=$attr; return attr;],
+dnl                        [attr_name=$attr; break])
+dnl	done
+dnl     AC_MSG_RESULT($attr_name)
+dnl     if test "$attr_name" != PTHREAD_CREATE_JOINABLE; then
+dnl         AC_DEFINE_UNQUOTED(PTHREAD_CREATE_JOINABLE, $attr_name,
+dnl                            [Define to necessary symbol if this constant
+dnl                             uses a non-standard name on your system.])
+dnl     fi
+
+        AC_MSG_CHECKING([if more special flags are required for pthreads])
+        flag=no
+        case "${host_cpu}-${host_os}" in
+            *-aix* | *-freebsd* | *-darwin*) flag="-D_THREAD_SAFE";;
+            # CS: Add _REENTRANT in Linux to emulate -pthread.
+            #
+            *-linux* | *solaris* | *-osf* | *-hpux*) flag="-D_REENTRANT";;
+        esac
+        AC_MSG_RESULT(${flag})
+        if test "x$flag" != xno; then
+            PTHREAD_CXXFLAGS="$flag $PTHREAD_CXXFLAGS"
+        fi
+
+        LIBS="$save_LIBS"
+        CXXFLAGS="$save_CXXFLAGS"
+
+dnl     # More AIX lossage: must compile with xlC_r
+dnl	if test x"$GXX" != xyes; then
+dnl          AC_CHECK_PROGS(PTHREAD_CXX, xlC_r, ${CXX})
+dnl        else
+dnl          PTHREAD_CXX=$CXX
+dnl	fi
+
+else
+        PTHREAD_CXX="$CXX"
+fi
+
+AC_SUBST(PTHREAD_LIBS)
+AC_SUBST(PTHREAD_CXXFLAGS)
+AC_SUBST(PTHREAD_CXX)
+
+# Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
+if test x"$acx_pthread_ok" = xyes; then
+        ifelse([$1],,AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.]),[$1])
+        :
+else
+        acx_pthread_ok=no
+        $2
+fi
+AC_LANG_RESTORE
+])dnl ACX_PTHREAD
diff --git a/m4/threads.m4 b/m4/threads.m4
new file mode 100644
index 0000000..4cd4c05
--- /dev/null
+++ b/m4/threads.m4
@@ -0,0 +1,60 @@
+dnl file      : m4/threads.m4
+dnl copyright : Copyright (c) 2009-2012 Code Synthesis Tools CC
+dnl license   : GNU GPL v2; see accompanying LICENSE file
+dnl
+AC_DEFUN([THREADS],[
+
+threads_thread_keyword=no
+
+AC_ARG_ENABLE(
+  [threads],
+  AS_HELP_STRING([--disable-threads], [disable threads (enabled by default)]),
+  [AS_IF([test x"$enableval" = xno], [threads=none], [threads=check])],
+  [threads=check])
+
+# If thread support is not disabled by the user, figure out what we can use.
+#
+if test x$threads = xcheck; then
+  case $host_os in
+    windows* | mingw*)
+      case $host_os in
+        mingw*)
+          CXXFLAGS="$CXXFLAGS -mthreads"
+          ;;
+      esac
+      threads=win32
+      ;;
+    *)
+      ACX_PTHREAD
+
+      if test x$acx_pthread_ok = xyes; then
+        threads=posix
+        LIBS="$LIBS $PTHREAD_LIBS"
+        CXXFLAGS="$CXXFLAGS $PTHREAD_CXXFLAGS"
+
+        # Check if we can use the __thread keyword.
+        #
+        AC_MSG_CHECKING([for __thread keyword])
+
+        CXX_LIBTOOL_LINK_IFELSE([
+          AC_LANG_SOURCE([
+            __thread int tls_var;
+
+            int
+            main ()
+            {
+              tls_var = 0;
+            }
+          ])],
+          [threads_thread_keyword=yes])
+
+        AC_MSG_RESULT([$threads_thread_keyword])
+      fi
+      ;;
+  esac
+fi
+
+if test x$threads = xcheck; then
+  AC_MSG_ERROR([thread support not available; use --disable-threads to force single-threaded mode])
+fi
+])dnl