summaryrefslogtreecommitdiff
path: root/tests/combined/testscript
blob: a6f827ba7145d0bdc24dddb827a82e77d3d6b112 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
# file      : tests/combined/testscript
# copyright : Copyright (c) 2009-2017 Code Synthesis Tools CC
# license   : MIT; see accompanying LICENSE file

: values
:
{
  : long
  :
  $* --foo=123 >'--foo=123'

  : short
  :
  $* -f=123 >'--foo=123'

  : empty
  :
  $* --foo= >'--foo='

  : unknown-option-long
  :
  $* --bar=123 2>>EOE != 0
  unknown option '--bar'
  EOE

  : unknown-option-short
  :
  $* -b=123 2>>EOE != 0
  unknown option '-b'
  EOE

  : unknown-value
  :
  $* --xyz=123 2>>EOE != 0
  invalid value '123' for option '--xyz'
  EOE

  : options-file
  :
  cat <<EOI >=options;
  --foo=123
  EOI
  $* --file=options >'--foo=123'
}

: flags
:
{
  : basic
  :
  $* -zyx >'-xyz'

  : separate
  :
  $* -zx -y >'-xyz'

  : long
  :
  $* --xyz >'--xyz'

  : unknown-option
  :
  $* -xYz 2>>EOE != 0
  unknown option '-Y'
  EOE

  : alnum-only
  :
  $* -xy+ 2>>EOE != 0
  unknown option '-xy+'
  EOE

  : flags-only
  :
  $* -xyf 123 2>>EOE != 0
  missing value for option '-f'
  EOE

  : flags-only-combined
  :
  $* -xyf=123 2>>EOE != 0
  missing value for option '-f'
  EOE
}